
    Planck.AI

planck_ai is a typed LLM provider abstraction for Elixir, built on top of
req_llm. It gives you a single, consistent
interface for streaming and completing requests across Anthropic, OpenAI, Google
Gemini, and any OpenAI-compatible endpoint — without leaking provider-specific
details into your application.
Installation
# mix.exs
{:planck_ai, "~> 0.1"}
Providers
	Provider	Atom	API key env var
	Anthropic (Claude)	:anthropic	ANTHROPIC_API_KEY
	OpenAI (GPT)	:openai	OPENAI_API_KEY
	Google (Gemini)	:google	GOOGLE_API_KEY
	OpenAI-compatible (NVIDIA, Groq, Ollama, llama.cpp, …)	:openai + base_url	<IDENTIFIER>_API_KEY or none

OpenAI-compatible endpoints (NVIDIA NIM, Groq, Ollama, llama.cpp, vLLM, etc.)
use the :openai provider atom with a base_url set. The optional identifier
field (e.g. "NVIDIA") derives the API key env var (NVIDIA_API_KEY); if
omitted it falls back to OPENAI_API_KEY, or "not-needed" when no key exists.
Quick start
alias Planck.AI
alias Planck.AI.{Context, Message}

# 1. Pick a model from the catalog
{:ok, model} = AI.get_model(:anthropic, "claude-sonnet-4-6")

# 2. Build a context
context = %Context{
  system: "You are a helpful assistant.",
  messages: [
    %Message{role: :user, content: [{:text, "What is the Planck length?"}]}
  ]
}

# 3. Stream the response
model
|> AI.stream(context, temperature: 0.7)
|> Enum.each(fn
  {:text_delta, text} -> IO.write(text)
  {:done, _meta}      -> IO.puts("")
  {:error, reason}    -> IO.puts("Error: #{inspect(reason)}")
  _                   -> :ok
end)

# Or block for the full message
{:ok, %Message{content: content}} = AI.complete(model, context)
Model catalog
Cloud providers (:anthropic, :openai, :google) source their catalog from
a bundled LLMDB snapshot loaded offline at startup — no network call required.
# List all providers
AI.list_providers()
#=> [:anthropic, :openai, :google]

# List models for a provider
AI.list_models(:anthropic)
#=> [%Planck.AI.Model{id: "claude-opus-4-7", ...}, ...]

# Fetch a specific model by ID
{:ok, model} = AI.get_model(:anthropic, "claude-sonnet-4-6")
{:error, :not_found} = AI.get_model(:anthropic, "does-not-exist")
Anthropic
models = AI.list_models(:anthropic)
{:ok, model} = AI.get_model(:anthropic, "claude-sonnet-4-6")
Requires ANTHROPIC_API_KEY.
OpenAI
models = AI.list_models(:openai)
{:ok, model} = AI.get_model(:openai, "gpt-4o")
Requires OPENAI_API_KEY.
Google Gemini
models = AI.list_models(:google)
{:ok, model} = AI.get_model(:google, "gemini-2.5-flash")
Requires GOOGLE_API_KEY. Models that support extended thinking have
supports_thinking: true set in the catalog. To enable thinking on a request,
pass the budget via the Google-specific opt:
AI.stream(model, context, google_thinking_budget: 8_192)
OpenAI-compatible endpoints
Any OpenAI-compatible server (NVIDIA NIM, Groq, Ollama, llama.cpp, vLLM, etc.)
uses the :openai provider with a base_url. Pass base_url: to list_models/2
to discover available models at runtime:
# Discover models from NVIDIA NIM
models = AI.list_models(:openai, base_url: "https://integrate.api.nvidia.com/v1", identifier: "NVIDIA")

# Discover models from a local Ollama instance
models = AI.list_models(:openai, base_url: "http://localhost:11434")

# Discover models from a local llama.cpp server
models = AI.list_models(:openai, base_url: "http://localhost:8080")
API keys are resolved from the environment at request time. The identifier
field determines the env var name: "NVIDIA" → NVIDIA_API_KEY. When
identifier is nil, OPENAI_API_KEY is used. For keyless local servers (Ollama,
llama.cpp), neither env var needs to be set — the adapter falls back to
"not-needed".
Per-model inference defaults
%Planck.AI.Model{} has a default_opts field for inference parameters that
should apply to every call for that model. Opts passed explicitly to stream/3
or complete/3 override the defaults.
model = %Planck.AI.Model{
  id: "meta/llama-3.3-70b-instruct",
  provider: :openai,
  base_url: "https://integrate.api.nvidia.com/v1",
  identifier: "NVIDIA",
  context_window: 128_000,
  max_tokens: 4_096,
  default_opts: [temperature: 0.6, receive_timeout: 600_000]
}

# temperature: 0.6 applies unless overridden
AI.stream(model, context)

# temperature: 0.3 overrides the model default
AI.stream(model, context, temperature: 0.3)
Config loader — Planck.AI.Config
Planck.AI.Config.from_config/2 builds a list of %Model{} structs from the
v0.1.6 config format: a providers map (user-keyed) and a models list where
each entry references a provider by key.
providers = %{
  "anthropic" => %{"type" => "anthropic"},
  "nvidia"    => %{"type" => "openai",
                   "base_url"   => "https://integrate.api.nvidia.com/v1",
                   "identifier" => "NVIDIA"},
  "local"     => %{"type" => "openai",
                   "base_url"    => "http://localhost:11434",
                   "has_api_key" => false}
}

models = [
  %{"id" => "sonnet",   "model" => "claude-sonnet-4-6",           "provider" => "anthropic"},
  %{"id" => "llama70b", "model" => "meta/llama-3.3-70b-instruct", "provider" => "nvidia",
    "params" => %{"temperature" => 0.6, "receive_timeout" => 600_000}},
  %{"id" => "llama3.2", "model" => "llama3.2",                    "provider" => "local"}
]

models = Planck.AI.Config.from_config(providers, models)
# => [%Planck.AI.Model{id: "sonnet", model: "claude-sonnet-4-6", provider: :anthropic}, ...]

model = Enum.find(models, &(&1.id == "llama70b"))
AI.stream(model, context)
Invalid entries (unknown provider key, unknown provider type, missing required
fields) are skipped with a warning; valid entries are returned.
Provider entry fields
	Field	Required	Description
	"type"	yes	"anthropic", "openai", or "google"
	"base_url"	no	Custom endpoint — required for OpenAI-compatible local servers
	"identifier"	no	Uppercase tag for API key env var ("NVIDIA" → NVIDIA_API_KEY)
	"has_api_key"	no	false skips key lookup entirely (Ollama, llama.cpp). Default: true

Model entry fields
	Field	Required	Description
	"id"	yes	User alias — used to look up the model
	"model"	yes	Provider model identifier sent to the API
	"provider"	yes	Key referencing a providers entry
	"params"	no	Inference parameters (temperature, max_tokens, etc.)

Streaming events
AI.stream/3 returns a lazy Enumerable of tagged tuples:
	Event	Meaning
	{:text_delta, string}	A chunk of assistant text
	{:thinking_delta, string}	A chunk of extended-thinking text
	{:tool_call_complete, %{id:, name:, args:}}	A fully-assembled tool call
	{:done, %{stop_reason:, usage:}}	Stream finished; usage stats included
	{:error, reason}	Transport or API error; stream halts

Exceptions raised during enumeration (e.g. a dropped HTTP connection) are
caught and emitted as {:error, exception} events, so the stream never raises.
Streaming patterns
Print text as it arrives
AI.stream(model, context)
|> Enum.each(fn
  {:text_delta, text} -> IO.write(text)
  {:done, _}          -> IO.puts("")
  {:error, reason}    -> IO.puts("\nError: #{inspect(reason)}")
  _                   -> :ok
end)
Forward events to another process
Since AI.stream/3 returns a lazy enumerable, you can run it in a Task and
send each event to a LiveView or any other process as chunks arrive:
parent = self()

Task.start(fn ->
  AI.stream(model, context)
  |> Stream.each(fn event -> send(parent, {:llm_event, event}) end)
  |> Stream.run()
end)

# Handle in a LiveView or GenServer:
def handle_info({:llm_event, {:text_delta, text}}, socket) do
  {:noreply, update(socket, :response, &(&1 <> text))}
end

def handle_info({:llm_event, {:done, _}}, socket) do
  {:noreply, assign(socket, :streaming, false)}
end

def handle_info({:llm_event, _}, socket), do: {:noreply, socket}
Inference parameters
All keyword opts accepted by AI.stream/3 and AI.complete/3 are forwarded
directly to req_llm, which handles per-provider translation:
AI.complete(model, context,
  temperature: 0.8,
  top_p:       0.95,
  max_tokens:  2_048
)
Tool calling
Define tools with Tool.new/1 and attach them to the context:
alias Planck.AI.Tool

read_file = Tool.new(
  name: "read_file",
  description: "Read the contents of a file",
  parameters: %{
    "type" => "object",
    "properties" => %{
      "path" => %{"type" => "string", "description" => "Absolute path to the file"}
    },
    "required" => ["path"]
  }
)

context = %Context{
  system: "You are a coding assistant.",
  messages: [
    %Message{role: :user, content: [{:text, "Show me lib/app.ex"}]}
  ],
  tools: [read_file]
}

{:ok, %Message{content: content}} = AI.complete(model, context)

# Inspect the tool calls in the response
for {:tool_call, id, name, args} <- content do
  IO.inspect({id, name, args})
end
To complete the loop, append a tool result message and call complete/3 again:
result_msg = %Message{
  role: :tool_result,
  content: [{:tool_result, call_id, File.read!(args["path"])}]
}

updated_context = %{context | messages: context.messages ++ [assistant_msg, result_msg]}
{:ok, final} = AI.complete(model, updated_context)
Multimodal input
Four content part types carry non-text data:
# Binary image
{:image, File.read!("photo.png"), "image/png"}

# Image by URL (all cloud providers)
{:image_url, "https://example.com/photo.png"}

# Binary file / document (Anthropic PDFs, Google files)
{:file, File.read!("report.pdf"), "application/pdf"}

# Video by URL (Google Gemini only)
{:video_url, "https://example.com/clip.mp4"}
%Message{
  role: :user,
  content: [
    {:image_url, "https://example.com/screenshot.png"},
    {:text, "What do you see in this image?"}
  ]
}
Support depends on the model's input_types field in the catalog.


  

    Changelog

v0.2.2
	Version bump to stay in sync with the monorepo release; no functional changes.

v0.2.1
	Version bump to stay in sync with the monorepo release; no functional changes.

v0.2.0
Default context_window raised to 32,768
Planck.AI.Config, the LLMDB catalog translation, and custom OpenAI-compatible
endpoint resolution all silently defaulted a missing context_window to
4_096. Since v0.1.6 dropped the old reconciliation against the bundled LLMDB
catalog for manually configured models, any model missing an explicit
context_window in .planck/config.json stayed capped at that value — which,
combined with more accurate context-usage estimation in planck_agent, could
trigger compaction before a single message was even sent. Raised to 32_768
as a safer generic fallback; still no substitute for setting the real value
for your model.
v0.1.13
Provider identifiers are sanitized instead of rejected
A provider's identifier (the tag used to derive its .env API key, e.g.
"NVIDIA" → NVIDIA_API_KEY) no longer fails the whole model load when it
contains spaces, punctuation, or lowercase letters. Planck.AI.Config now
normalizes it instead: upcased, disallowed characters replaced with _, and
leading non-letters stripped — e.g. "Qwen 3.6 27B" becomes "QWEN_3_6_27B".
An identifier with no letters at all (e.g. "3.6") still fails to load.
Unknown model params are forwarded via extra_body instead of dropped
Previously, any key in a model's params map that wasn't a recognized
req_llm option (temperature, max_tokens, top_p, top_k, min_p,
receive_timeout, anthropic_prompt_cache, anthropic_prompt_cache_ttl) was
silently dropped with a log warning — losing backend-specific sampler knobs
like llama.cpp's repetition_penalty or presence_penalty. These are now
automatically merged into extra_body and forwarded verbatim in the request
body, same as if you'd nested them there yourself. Nothing you put in params
is silently lost anymore.
v0.1.12
extra_body support in model params
Models can now include an extra_body key in their params config. Its value
is a map that gets merged verbatim into the HTTP request body just before it is
sent, enabling provider-specific fields that Planck and req_llm don't expose
natively.
Primary use cases:
	NVIDIA NIM / llama.cpp / vLLM — chat_template_kwargs to control
per-request template behaviour (e.g. {"thinking": false} to disable
chain-of-thought on DeepSeek/Qwen3 models)
	Any OpenAI-compatible endpoint with vendor extensions

{ "id": "deepseek", "model": "deepseek-ai/deepseek-v4-pro", "provider": "nvidia",
  "params": { "extra_body": { "chat_template_kwargs": { "thinking": false } } } }
NVIDIA NIM default model updated
Default model for new NVIDIA NIM providers changed from
qwen/qwen3-coder-480b-a35b-instruct to deepseek-ai/deepseek-v4-pro.
Default temperature updated to 1.0 and top_p to 0.95 to match
NVIDIA's recommended settings for this model.
v0.1.11
	Version bump to stay in sync with the monorepo release; no functional changes.

v0.1.10
Credential-proxy support
LLM requests can now be routed through an HTTPS MITM proxy (e.g. agent-vault).
Two new config keys in Planck.AI.Config:
	tool_proxy — HTTP proxy URL (e.g. http://vault:14322)
	tool_proxy_ca_cert — path to the proxy's CA certificate PEM file

When set, the Finch pool used for LLM calls is configured with
connect_options: [proxy: url] and ssl: [cacertfile: path], allowing the
proxy to intercept requests and inject credentials transparently.
v0.1.9
	Version bump to stay in sync with the monorepo release; no functional changes.

v0.1.8
	Version bump; pin Burrito OTP build version to 28.5.0 to fix macOS binary builds.

v0.1.7
	Version bump to stay in sync with the monorepo release; no functional changes.

v0.1.6
	Drop :custom_openai, :ollama, and :llama_cpp providers — public provider
atoms are now :anthropic | :openai | :google only
	:openai with base_url set routes to the OpenAI-compatible adapter (previously
required :custom_openai); without base_url routes to the standard OpenAI path
	identifier defaults to "OPENAI" on :openai models when nil — resolves
OPENAI_API_KEY for local endpoints that don't need a key
	Planck.AI.Models.OpenAI.all/1 now accepts a base_url: opt to query a custom
server's /models endpoint; without it returns the LLMDB catalog as before
	Planck.AI.Models.CustomOpenAI, Planck.AI.Models.Ollama, and
Planck.AI.Models.LlamaCpp removed — superseded by :openai + base_url
	Planck.AI.Model gains model field — the actual provider model identifier
(e.g. "claude-sonnet-4-6"); id becomes the user-facing alias. The adapter
uses model || id so structs without the new field keep working
	Planck.AI.Model gains has_api_key: boolean() (default true); when false,
the adapter passes "not-needed" directly and skips env-var lookup — for local
servers like Ollama that require no authentication
	Planck.AI.Config functions from_map/1, from_list/1, and load/1 removed — superseded
by from_config/2
	Planck.AI.Config.from_config/2 added — builds [Model.t()] from a providers
map (user-keyed, each entry has a "type" field) and a models list (each entry
references a provider key); this is the v0.1.6 config format

v0.1.5
	New :custom_openai provider for OpenAI-compatible endpoints (NVIDIA, Together, vLLM, etc.)
	Planck.AI.Model gains an identifier field — a short uppercase tag (e.g. "NVIDIA") used to derive the env var <IDENTIFIER>_API_KEY at request time
	Planck.AI.Models.CustomOpenAI — factory (model/2) and runtime discovery (all/1) via GET {base_url}/models
	Planck.AI.Config from_map/1 validates and upcases identifier; rejects values that don't match [A-Z][A-Z0-9]*
	API keys for :custom_openai are resolved lazily from the environment at request time, never cached

v0.1.4
	Version bump to stay in sync with the monorepo release; no functional changes.

v0.1.3
	Version bump to stay in sync with the monorepo release; no functional changes.

v0.1.2
	Version bump to stay in sync with the monorepo release; no functional changes.

v0.1.1
	ex_doc bumped to ~> 0.40.2; no functional changes.

v0.1.0
First release.
	Provider-agnostic streaming and completion API over req_llm
	Lazy event-tuple stream ({:text_delta, _}, {:thinking_delta, _}, {:tool_call_complete, _}, {:done, _}, {:error, _})
	Tool calling with streaming argument assembly
	Model catalog for Anthropic, OpenAI, and Google via LLMDB
	Local server support for Ollama and llama.cpp with runtime model discovery
	JSON config loader (Planck.AI.Config)
	Multimodal input: text, image, image_url, file, video_url
	parse_provider/1 (private) — String.to_existing_atom →
String.to_atom; @valid_providers derived from Planck.AI.list_providers()
at compile time (single source of truth). Private function specs added.



  

    
Planck.AI 
    



      
Typed LLM provider abstraction built on top of req_llm.
Planck.AI provides a provider-agnostic interface for streaming and completing
LLM requests. It defines the canonical types (Model, Message, Context, Tool)
and streaming event protocol (Stream) consumed by Planck.Agent.
Streaming
model = Planck.AI.Models.Anthropic.all() |> hd()
context = %Planck.AI.Context{
  system: "You are a helpful assistant.",
  messages: [%Planck.AI.Message{role: :user, content: [{:text, "Hello!"}]}]
}

model
|> Planck.AI.stream(context, temperature: 0.7)
|> Enum.each(fn
  {:text_delta, text} -> IO.write(text)
  {:done, _} -> IO.puts("")
  _ -> :ok
end)
Completing
{:ok, message} = Planck.AI.complete(model, context)
Model catalog
Planck.AI.list_providers()
#=> [:anthropic, :openai, :ollama, :llama_cpp]

Planck.AI.list_models(:anthropic)
#=> [%Planck.AI.Model{id: "claude-opus-4-5", ...}, ...]

{:ok, model} = Planck.AI.get_model(:anthropic, "claude-sonnet-4-6")

    Functions
  


    
      
        complete(model, context, opts \\ [])

      


        Sends a request to the LLM and blocks until the full response is received.



    


    
      
        get_model(provider, id, opts \\ [])

      


        Looks up a model by provider and id.



    


    
      
        list_models(provider, opts \\ [])

      


        Returns all known models for a given provider.



    


    
      
        list_providers()

      


        Returns all supported provider atoms.



    


    
      
        stream(model, context, opts \\ [])

      


        Streams a request to the LLM, returning a lazy stream of StreamEvent tuples.



    





      


      
        Functions


        


    

  
    
      
    
    
      complete(model, context, opts \\ [])



        
          
        

    

  


  

      

          @spec complete(Planck.AI.Model.t(), Planck.AI.Context.t(), keyword()) ::
  {:ok, Planck.AI.Message.t()} | {:error, term()}


      


Sends a request to the LLM and blocks until the full response is received.
Internally consumes stream/3 and assembles a Message from the events.
Returns {:ok, message} on success or {:error, reason} on failure.
Examples
{:ok, %Planck.AI.Message{} = message} = Planck.AI.complete(model, context)

  



    

  
    
      
    
    
      get_model(provider, id, opts \\ [])



        
          
        

    

  


  

      

          @spec get_model(atom(), String.t(), keyword()) ::
  {:ok, Planck.AI.Model.t()} | {:error, :not_found}


      


Looks up a model by provider and id.
Returns {:ok, model} if found, {:error, :not_found} otherwise.
Examples
iex> Planck.AI.get_model(:anthropic, "claude-sonnet-4-6")
{:ok, %Planck.AI.Model{id: "claude-sonnet-4-6", ...}}

iex> Planck.AI.get_model(:anthropic, "does-not-exist")
{:error, :not_found}

iex> Planck.AI.get_model(:llama_cpp, "mistral-7b", base_url: "http://10.0.0.5:8080")
{:ok, %Planck.AI.Model{id: "mistral-7b", ...}}

  



    

  
    
      
    
    
      list_models(provider, opts \\ [])



        
          
        

    

  


  

      

          @spec list_models(atom(), keyword()) :: [Planck.AI.Model.t()]


      


Returns all known models for a given provider.
Cloud providers (:anthropic, :openai, :google) source their catalog from
LLMDB — a bundled snapshot loaded into :persistent_term on first call.
For OpenAI-compatible custom endpoints, pass base_url: in opts to query
the server's /models endpoint at call time instead of the LLMDB catalog.
Examples
iex> Planck.AI.list_models(:anthropic)
[%Planck.AI.Model{provider: :anthropic, ...}, ...]

iex> Planck.AI.list_models(:openai, base_url: "https://integrate.api.nvidia.com/v1")
[%Planck.AI.Model{provider: :openai, ...}, ...]

  



  
    
      
    
    
      list_providers()



        
          
        

    

  


  

      

          @spec list_providers() :: [atom()]


      


Returns all supported provider atoms.
Examples
iex> Planck.AI.list_providers()
[:anthropic, :openai, :google]

  



    

  
    
      
    
    
      stream(model, context, opts \\ [])



        
          
        

    

  


  

      

          @spec stream(Planck.AI.Model.t(), Planck.AI.Context.t(), keyword()) ::
  Enumerable.t(Planck.AI.Stream.t())


      


Streams a request to the LLM, returning a lazy stream of StreamEvent tuples.
Keyword opts (e.g. temperature: 0.7, max_tokens: 2048) are forwarded
directly to req_llm, which handles per-provider parameter translation.
Examples
Planck.AI.stream(model, context, temperature: 1.0)
|> Enum.each(fn
  {:text_delta, t} -> IO.write(t)
  _ -> :ok
end)

  


        

      


  

    
Planck.AI.Adapter 
    



      
Translates between Planck's types and req_llm's call interface.
This is the only module that knows req_llm's input and output shapes.
Everything above this layer works exclusively with Planck.AI structs.

      


      
        Summary


  
    Functions
  


    
      
        to_req_llm(model, context, opts)

      


        Converts a Planck.AI.Model, Planck.AI.Context, and call-site opts into
the three arguments expected by req_llm's stream_text/3:
{model_spec_string, req_llm_context, opts}.

      to_req_llm(model, context, opts)



        
          
        

    

  


  

      

          @spec to_req_llm(Planck.AI.Model.t(), Planck.AI.Context.t(), keyword()) ::
  {model_spec, req_llm_context, opts}
when model_spec: String.t() | map(),
     req_llm_context: ReqLLM.Context.t(),
     opts: keyword()


      


Converts a Planck.AI.Model, Planck.AI.Context, and call-site opts into
the three arguments expected by req_llm's stream_text/3:
{model_spec_string, req_llm_context, opts}.
Tools from the context are added to opts as %ReqLLM.Tool{} structs.
Inference params (e.g. temperature:, max_tokens:) in opts are forwarded
directly to req_llm, which handles per-provider translation.
Examples
iex> model = %Planck.AI.Model{id: "claude-sonnet-4-6", provider: :anthropic, context_window: 200_000, max_tokens: 8_096}
iex> context = %Planck.AI.Context{messages: []}
iex> {model_spec, _ctx, _opts} = Planck.AI.Adapter.to_req_llm(model, context, [])
iex> model_spec
"anthropic:claude-sonnet-4-6"

  


        

      


  

    
Planck.AI.Config 
    



      
Converts model configuration into Planck.AI.Model structs.
The entry point is from_config/2, which accepts the v0.1.6 config format:
a providers map (user-keyed) and a models list where each entry references
a provider by key.
Format
providers = %{
  "anthropic" => %{"type" => "anthropic"},
  "nvidia"    => %{"type" => "openai", "base_url" => "https://integrate.api.nvidia.com/v1", "identifier" => "NVIDIA"},
  "local"     => %{"type" => "openai", "base_url" => "http://localhost:11434", "has_api_key" => false}
}

models = [
  %{"id" => "sonnet",   "model" => "claude-sonnet-4-6",             "provider" => "anthropic"},
  %{"id" => "llama70b", "model" => "meta/llama-3.3-70b-instruct",   "provider" => "nvidia"},
  %{"id" => "llama3.2", "model" => "llama3.2",                      "provider" => "local"}
]

models = Planck.AI.Config.from_config(providers, models)

      


      
        Summary


  
    Functions
  


    
      
        from_config(providers, models)

      


        Builds a list of Model structs from the v0.1.6 config format, which separates
provider entries (keyed map) from model entries (list).



    


    
      
        sanitize_identifier(raw)

      


        Normalizes a user-supplied identifier into a valid env-var tag: upcased,
characters outside A-Z0-9 replaced with _, and leading non-letter
characters stripped (env var names must start with a letter).

      from_config(providers, models)



        
          
        

    

  


  

      

          @spec from_config(%{required(String.t()) => map()}, [map()]) :: [Planck.AI.Model.t()]


      


Builds a list of Model structs from the v0.1.6 config format, which separates
provider entries (keyed map) from model entries (list).
Each model entry must reference a key in providers via its "provider" field.
Invalid entries are skipped with a warning; the rest are returned.

          @spec sanitize_identifier(String.t()) :: {:ok, String.t()} | :error


      


Normalizes a user-supplied identifier into a valid env-var tag: upcased,
characters outside A-Z0-9 replaced with _, and leading non-letter
characters stripped (env var names must start with a letter).
Used both when loading config (so a typo'd identifier degrades to a
usable tag instead of dropping the model) and when writing config via
Planck.Headless.configure_provider/1 (so the persisted identifier and
the .env key it derives always agree).
Returns :error only when nothing but non-letters remains (e.g. "3.6").
iex> Planck.AI.Config.sanitize_identifier("Qwen 3.6 27B")
{:ok, "QWEN_3_6_27B"}

iex> Planck.AI.Config.sanitize_identifier("nvidia")
{:ok, "NVIDIA"}

  


        

      


  

    
Planck.AI.Context 
    



      
Everything sent to the LLM in a single request: system prompt, conversation
history, and available tools.
Inference parameters (temperature, max_tokens, etc.) are NOT stored here —
they are passed as keyword options at the Planck.AI.stream/3 or
Planck.AI.complete/3 call site and forwarded directly to req_llm.
Examples
iex> %Planck.AI.Context{
...>   system: "You are a helpful coding assistant.",
...>   messages: [
...>     %Planck.AI.Message{role: :user, content: [{:text, "Hello"}]}
...>   ],
...>   tools: []
...> }

      


      
        Summary


  
    Types
  


    
      
        t()

      


    





  
    Functions
  


    
      
        estimate_tokens(context)

      


        Rough token estimate for the entire request this context represents —
system prompt, conversation, and tool schemas.

          @type t() :: %Planck.AI.Context{
  messages: [Planck.AI.Message.t()],
  system: String.t() | nil,
  tools: [Planck.AI.Tool.t()]
}

      estimate_tokens(context)



        
          
        

    

  


  

      

          @spec estimate_tokens(t()) :: non_neg_integer()


      


Rough token estimate for the entire request this context represents —
system prompt, conversation, and tool schemas.
A live "how much context is used" figure needs all three: the system
prompt alone is routinely the largest single piece (tool guidance,
skills, AGENTS.md), and tool schemas sent on every request can be
substantial too once several tools are registered — estimating only the
conversation messages undercounts by everything actually sent alongside
them. This is the actual t() about to be (or just was) sent, not a
reconstruction of it from separate pieces that can drift out of sync
with each other. This is also the one place per-content-part token
counting is written — a caller holding Planck.Agent.Message.t() structs
converts via Planck.Agent.Message.to_ai_messages/1 and wraps the result
in a bare %__MODULE__{} (system/tools left at their defaults for a
messages-only estimate) rather than duplicating this logic for its own
message type.

  


        

      


  

    
Planck.AI.Message 
    



      
A single conversation turn with a role and a list of typed content parts.
Content is always a list of tagged tuples, mirroring the Anthropic API's
multi-part message format. An assistant message may contain both text and
tool calls interleaved.
Content part types
	{:text, text} — plain text
	{:image, data, mime_type} — binary image data with MIME type
	{:image_url, url} — image referenced by URL
	{:file, data, mime_type} — binary file/document (PDF, etc.)
	{:video_url, url} — video referenced by URL (Google Gemini only)
	{:tool_call, id, name, args} — a tool call emitted by the model
	{:tool_result, id, result} — the result of executing a tool call
	{:thinking, text} — extended thinking / reasoning block

Examples
iex> %Planck.AI.Message{
...>   role: :user,
...>   content: [{:text, "What is the weather in Lisbon?"}]
...> }

          @type content_part() ::
  {:text, String.t()}
  | {:image, binary(), String.t()}
  | {:image_url, String.t()}
  | {:file, binary(), String.t()}
  | {:video_url, String.t()}
  | {:tool_call, String.t(), String.t(), map()}
  | {:tool_result, String.t(), term()}
  | {:thinking, String.t()}


      



  



  
    
      
    
    
      role()



        
          
        

    

  


  

      

          @type role() :: :user | :assistant | :tool_result

          @type t() :: %Planck.AI.Message{content: [content_part()], role: role()}


      



  


        

      


  

    
Planck.AI.Model 
    



      
Represents an LLM model and its metadata.
The base_url field is used for self-hosted or OpenAI-compatible endpoints
(llama.cpp, vLLM, LM Studio). When nil, the provider's default endpoint is used.
Examples
iex> %Planck.AI.Model{
...>   id: "claude-sonnet-4-6",
...>   name: "Claude Sonnet 4.6",
...>   provider: :anthropic,
...>   context_window: 200_000,
...>   max_tokens: 8096,
...>   supports_thinking: true,
...>   input_types: [:text, :image]
...> }

        Per-token cost in USD per million tokens.



    


    
      
        provider()

      


        Supported LLM provider backends.



    


    
      
        t()

      


        An LLM model struct.

        Returns the list of supported provider atoms.

          @type cost() :: %{
  input: float(),
  output: float(),
  cache_read: float(),
  cache_write: float()
}


      


Per-token cost in USD per million tokens.

          @type provider() :: :anthropic | :openai | :google


      


Supported LLM provider backends.

  



  
    
      
    
    
      t()



        
          
        

    

  


  

      

          @type t() :: %Planck.AI.Model{
  api_key: String.t() | nil,
  base_url: String.t() | nil,
  context_window: pos_integer(),
  cost: cost(),
  default_opts: keyword(),
  has_api_key: boolean(),
  id: String.t(),
  identifier: String.t() | nil,
  input_types: [:text | :image | :image_url | :file | :video_url],
  max_tokens: pos_integer(),
  model: String.t() | nil,
  name: String.t(),
  provider: provider(),
  supports_thinking: boolean()
}


      


An LLM model struct.
	id — user-facing alias (e.g. "sonnet"); used to look up the model in config.
	model — actual API identifier sent to the provider (e.g. "claude-sonnet-4-6");
falls back to id when nil (legacy flat-config path).
	identifier — uppercase env-var prefix for custom OpenAI-compat providers
(e.g. "NVIDIA" → resolves NVIDIA_API_KEY).
	has_api_key — when false, the adapter skips env-var lookup and sends
"not-needed" as the API key (for local servers like llama.cpp).
	api_key — not used at runtime; reserved for future in-memory overrides.

          @spec providers() :: [provider()]


      


Returns the list of supported provider atoms.

  


        

      


  

    
Planck.AI.ModelProvider behaviour
    



      
Behaviour for modules that supply a list of Planck.AI.Model structs.
Cloud providers (Anthropic, OpenAI, Google)
These source their catalog from LLMDB, a bundled snapshot of the public model
registry. No network call is made at query time — the data is loaded from the
package artifact into :persistent_term on first access.
Local providers (Ollama, llama.cpp)
These fetch the model list from the running local server at call time, so the
returned list reflects whatever models are currently loaded.
Error handling
All implementations must return [] on any failure — they must never raise.

      all(keyword)



        
          
        

    

  


  

      

          @callback all(keyword()) :: [Planck.AI.Model.t()]


      



  


        

      


  

    
Planck.AI.Models.Anthropic 
    



      
Model catalog for Anthropic's Claude family, sourced from LLMDB.

      




  

    
Planck.AI.Models.Google 
    



      
Model catalog for Google's Gemini family, sourced from LLMDB.
Requires the GOOGLE_API_KEY environment variable (or pass api_key: in opts).

      




  

    
Planck.AI.Models.OpenAI 
    



      
Model catalog for OpenAI and OpenAI-compatible endpoints.
Without options, returns the LLMDB catalog for OpenAI's GPT family (requires
OPENAI_API_KEY). With a base_url: option, queries the server's /models
endpoint at call time — use this for NVIDIA NIM, Groq, Ollama, llama.cpp, etc.
Examples
# Cloud catalog
Planck.AI.Models.OpenAI.all()

# Custom endpoint
Planck.AI.Models.OpenAI.all(
  base_url: "https://integrate.api.nvidia.com/v1",
  identifier: "NVIDIA"
)

# Build a single model struct
Planck.AI.Models.OpenAI.model("deepseek-ai/deepseek-v4-pro",
  base_url: "https://integrate.api.nvidia.com/v1",
  identifier: "NVIDIA",
  context_window: 128_000
)

        all(opts \\ [])

      


        Returns models for this provider.

          @spec all(keyword()) :: [Planck.AI.Model.t()]


      


Returns models for this provider.
Without base_url:, returns the LLMDB snapshot for OpenAI.
With base_url:, queries the server's /models endpoint.
Options (custom endpoint only)
	:base_url — base URL of the server.
	:identifier — uppercase tag for env var derivation (e.g. "NVIDIA" →
NVIDIA_API_KEY). Defaults to "OPENAI".
	:context_window — default context window. Defaults to 32_768.
	:max_tokens — default max tokens. Defaults to 2_048.


  


        

      


  

    
Planck.AI.ReqLLMBehaviour behaviour
    



      
Behaviour wrapping the req_llm streaming call.
Exists so that Planck.AI.Adapter can be tested without making real HTTP
requests. In production, Planck.AI.ReqLLM (internal) delegates directly to
ReqLLM.stream_text/3. In tests, Planck.AI.MockReqLLM is injected via
application config.

      stream_text(model_spec, messages, opts)



        
          
        

    

  


  

      

          @callback stream_text(model_spec :: term(), messages :: term(), opts :: keyword()) ::
  {:ok, term()} | {:error, term()}


      



  


        

      


  

    
Planck.AI.Stream 
    



      
Streaming event types and normalization from req_llm chunks.
req_llm emits %ReqLLM.StreamChunk{} structs with a :type field.
from_req_llm/1 maps each chunk type to the canonical event tuples consumed
by Planck.Agent and callers of Planck.AI.stream/3.
Tool call arguments arrive as JSON fragments spread across multiple :meta
chunks. This module buffers the fragments and emits a single assembled
{:tool_call_complete, ...} per tool call when the stream finishes.
Exceptions raised during stream consumption (e.g. ReqLLM.Error.API.Stream
on HTTP errors) are caught and emitted as {:error, exception} events,
halting the stream gracefully.
Event types
	{:text_delta, text} — a chunk of assistant text
	{:thinking_delta, text} — a chunk of extended thinking / reasoning
	{:tool_call_complete, %{id, name, args}} — a fully assembled tool call
	{:done, %{stop_reason, usage}} — stream finished; includes token usage
	{:error, reason} — an error occurred during streaming


      


      
        Summary


  
    Types
  


    
      
        done()

      


    


    
      
        t()

      


    


    
      
        tool_call()

        from_req_llm(chunks)

      


        Converts a stream of ReqLLM.StreamChunk structs into event tuples.



    





      


      
        Types


        


  
    
      
    
    
      done()



        
          
        

    

  


  

      

          @type done() :: %{stop_reason: atom(), usage: usage()}

          @type t() ::
  {:text_delta, String.t()}
  | {:thinking_delta, String.t()}
  | {:tool_call_complete, tool_call()}
  | {:done, done()}
  | {:error, term()}


      



  



  
    
      
    
    
      tool_call()



        
          
        

    

  


  

      

          @type tool_call() :: %{id: String.t(), name: String.t(), args: map()}

          @type usage() :: %{input_tokens: non_neg_integer(), output_tokens: non_neg_integer()}

          @spec from_req_llm(Enumerable.t()) :: Enumerable.t(t())


      


Converts a stream of ReqLLM.StreamChunk structs into event tuples.
Examples
iex> chunks = [
...>   %{type: :content, text: "Hello"},
...>   %{type: :meta, metadata: %{finish_reason: :stop, usage: %{input_tokens: 10, output_tokens: 5}}}
...> ]
iex> chunks |> Planck.AI.Stream.from_req_llm() |> Enum.to_list()
[{:text_delta, "Hello"}, {:done, %{stop_reason: :stop, usage: %{input_tokens: 10, output_tokens: 5}}}]

  


        

      


  

    
Planck.AI.Tool 
    



      
Defines a tool that can be called by the model during a conversation.
The parameters field is a JSON Schema map describing the tool's input.
Examples
iex> Planck.AI.Tool.new(
...>   name: "bash",
...>   description: "Execute a shell command",
...>   parameters: %{
...>     "type" => "object",
...>     "properties" => %{
...>       "command" => %{"type" => "string", "description" => "The command to run"}
...>     },
...>     "required" => ["command"]
...>   }
...> )
%Planck.AI.Tool{name: "bash", description: "Execute a shell command", parameters: %{"type" => "object", "properties" => %{"command" => %{"type" => "string", "description" => "The command to run"}}, "required" => ["command"]}}

        t()

        new(opts)

      


        Builds a %Planck.AI.Tool{} struct from keyword options.

          @type t() :: %Planck.AI.Tool{
  description: String.t(),
  name: String.t(),
  parameters: map()
}

      new(opts)



        
          
        

    

  


  

      

          @spec new(keyword()) :: t()


      


Builds a %Planck.AI.Tool{} struct from keyword options.
Options
	:name — tool name (required)
	:description — human-readable description (required)
	:parameters — JSON Schema map describing the tool's input (required)

